audrey_sources = [
  'application.vala',
  'globalconf.vala',
  'mpris.vala',
  'playbin.vala',
  'subsonic.vala',
  'ui/play_queue.vala',
  'ui/playbar.vala',
  'ui/setup.vala',
  'ui/window.vala',
]

audrey_deps = [
  dependency('gtk4', version: '>= 4.16'),
  dependency('json-glib-1.0', version: '>= 1.10'),
  dependency('libadwaita-1', version: '>= 1.6'),
  dependency('libgcrypt', version: '>= 1.11'),
  dependency('libsecret-1', version: '>= 0.21'),
  dependency('libsoup-3.0', version: '>= 3.6'),
  dependency('mpv', version: '>= 2.3'),
]

audrey_sources += removeme

configure_file(
  output: 'meson_config.rs',
  input: 'meson_config.rs.in',
  configuration: config_h,
)
# awful hack to put the configured file back in source
run_command(
  'cp',
  meson.project_build_root() / 'src' / 'meson_config.rs',
  meson.project_source_root() / 'src' / 'meson_config.rs',
  check: true,
)

audrey_c = static_library(
  'audrey',
  audrey_sources,
  dependencies: audrey_deps,
  include_directories: config_inc,
  install: true,
  vala_args: [
    '--vapidir',
    meson.current_source_dir() / 'vapi',
    '--gresources',
    meson.project_source_root() / 'resources/audrey.gresource.xml',
  ],
  vala_header: 'audrey.h',
  vala_gir: 'audrey-0.gir',
)