errordomain SubsonicError {
    BAD_AUTHN,
    ERROR,
}

public delegate void SongCallback (Song song);

public class Artist : Object, Json.Serializable {
    public string index;
    public string id;
    public string name { get; private set; }
    public string? cover_art;
    public string? artist_image_url;
    public int64 album_count;

    public Artist (string index, Json.Reader reader) {
        this.index = index;

        reader.read_member ("id");
        this.id = reader.get_string_value ();
        reader.end_member ();

        reader.read_member ("name");
        this.name = reader.get_string_value ();
        reader.end_member ();

        reader.read_member ("coverArt");
        this.cover_art = reader.get_string_value ();
        reader.end_member ();

        reader.read_member ("artistImageUrl");
        this.artist_image_url = reader.get_string_value ();
        reader.end_member ();

        reader.read_member ("albumCount");
        this.album_count = reader.get_int_value ();
        reader.end_member ();
    }
}

public class Album : Object {
    public string id;
    public string name;

    public Album (Json.Reader reader) {
        reader.read_member ("id");
        this.id = reader.get_string_value ();
        reader.end_member ();

        reader.read_member ("name");
        this.name = reader.get_string_value ();
        reader.end_member ();
    }
}

public class Song : Object {
    public string id { get; private set; }
    public string title { get; private set; }
    public string album { get; private set; }
    public string artist { get; private set; }
    public int64 track { get; private set; }
    public int64 year { get; private set; }
    public DateTime? starred { get; private set; }

    public Song (Json.Reader reader) {
        reader.read_member ("id");
        this.id = reader.get_string_value ();
        reader.end_member ();

        reader.read_member ("title");
        this.title = reader.get_string_value ();
        reader.end_member ();

        reader.read_member ("album");
        this.album = reader.get_string_value ();
        reader.end_member ();

        reader.read_member ("artist");
        this.artist = reader.get_string_value ();
        reader.end_member ();

        reader.read_member ("track");
        this.track = reader.get_int_value ();
        reader.end_member ();

        reader.read_member ("year");
        this.year = reader.get_int_value ();
        reader.end_member ();
    }
}

public struct API.PlayQueue {
    public string current;
    public int64 position;
    public DateTime changed;
    public string changed_by;
    public ListStore songs;

    internal PlayQueue.from_reader (Json.Reader reader) {
        reader.read_member ("current");
        this.current = reader.get_string_value ();
        reader.end_member ();

        reader.read_member ("position");
        this.position = reader.get_int_value ();
        reader.end_member ();

        reader.read_member ("changed");
        this.changed = new DateTime.from_iso8601 (reader.get_string_value (), null);
        reader.end_member ();

        reader.read_member ("changed_by");
        this.changed_by = reader.get_string_value ();
        reader.end_member ();

        //print("%s %lli %s %s\n",this.current, this.position, this.changed, this.changed_by);

        this.songs = new ListStore (typeof (Song));

        reader.read_member ("song");
        for (int i = 0; i < reader.count_elements (); i += 1) {
            reader.read_element (i);
            this.songs.append (new Song (reader));
            reader.end_element ();
        }
        reader.end_member ();
        assert (reader.get_error () == null);
    }
}

public class Subsonic : Object {
    public ListStore artist_list;
    public ListStore album_list;
    public ListStore song_list;

    private Soup.Session session;
    private string url;
    private string parameters;

    public Subsonic.with_password (string url, string username, string password) {
        this.url = url;
        this.parameters = @"u=$(Uri.escape_string(username))&p=$(Uri.escape_string(password))&v=1.16.1&c=eu.callcc.audrey";

        this.session = new Soup.Session ();
        this.session.user_agent = "audrey/0.1.0 (Linux)"; // AUDREY_VERSION

        this.artist_list = new ListStore (typeof (Artist));
        this.album_list = new ListStore (typeof (Album));
        this.song_list = new ListStore (typeof (Song));
    }

    public Subsonic.with_token (string url, string username, string token, string salt) {
        this.url = url;
        this.parameters = @"u=$(Uri.escape_string(username))&t=$(Uri.escape_string(token))&s=$(Uri.escape_string(salt))&v=1.16.1&c=eu.callcc.audrey";

        this.session = new Soup.Session ();

        this.artist_list = new ListStore (typeof (Artist));
        this.album_list = new ListStore (typeof (Album));
        this.song_list = new ListStore (typeof (Song));
    }

    private void unwrap_response (Json.Reader reader) throws Error {
        reader.read_member ("subsonic-response");

        reader.read_member ("status");
            if (reader.get_string_value () != "ok") {
                reader.end_member ();
                reader.read_member ("error");
                reader.read_member ("message");
                throw new SubsonicError.ERROR (reader.get_string_value () ?? "???");
            }
        reader.end_member();
    }

    public async void ping () throws Error {
        var msg = new Soup.Message ("GET", @"$(this.url)/rest/ping?f=json&$(this.parameters)");
        if (msg == null) {
            throw new SubsonicError.BAD_AUTHN ("Bad message");
        }

        var bytes = yield this.session.send_and_read_async (msg, Priority.DEFAULT, null);
        assert (msg.get_status () == Soup.Status.OK);

        var parser = new Json.Parser ();
        parser.load_from_data ((string) bytes.get_data ());
        
        var reader = new Json.Reader (parser.get_root ());
        this.unwrap_response (reader);
    }

    public async void scrobble (string id) throws Error {
        var msg = new Soup.Message ("GET", @"$(this.url)/rest/scrobble?id=$(Uri.escape_string (id))&f=json&$(this.parameters)");
        assert (msg != null);

        var bytes = yield this.session.send_and_read_async (msg, Priority.DEFAULT, null);
        assert (msg.get_status () == Soup.Status.OK);

        var parser = new Json.Parser ();
        parser.load_from_data ((string) bytes.get_data ());
        
        var reader = new Json.Reader (parser.get_root ());
        this.unwrap_response (reader);
    }

    public async void get_random_songs (string? parameters, SongCallback callback) throws Error {
        string str_parameters;
        if (parameters == null) {
            str_parameters = "";
        } else {
            str_parameters = @"$parameters&";
        }

        var msg = new Soup.Message("GET", @"$(this.url)/rest/getRandomSongs?$(str_parameters)size=500&f=json&$(this.parameters)");
        assert (msg != null);

        var bytes = yield this.session.send_and_read_async (msg, Priority.DEFAULT, null);
        assert (msg.get_status () == Soup.Status.OK);

        var parser = new Json.Parser ();
        parser.load_from_data ((string) bytes.get_data ());

        var reader = new Json.Reader (parser.get_root ());
        this.unwrap_response (reader);

        reader.read_member ("randomSongs");
        reader.read_member ("song");

        for (int i = 0; i < reader.count_elements (); i += 1) {
            reader.read_element (i);
            callback (new Song (reader));
            reader.end_element ();
        }

        assert (reader.get_error () == null);
    }

    public string stream_uri (string id) {
        return @"$(this.url)/rest/stream?id=$(Uri.escape_string(id))&$(this.parameters)";
    }

    public string cover_art_uri (string id, int size) {
        return @"$(this.url)/rest/getCoverArt?id=$(Uri.escape_string(id))&$(size)&$(this.parameters)";
    }

    public async Gdk.Pixbuf cover_art (string id, int size, Cancellable cancellable) throws Error {
        var msg = new Soup.Message("GET", this.cover_art_uri (id, size));
        assert (msg != null);

        var stream = yield this.session.send_async (msg, Priority.DEFAULT, cancellable);
        assert (msg.get_status () == Soup.Status.OK);
        return yield new Gdk.Pixbuf.from_stream_async (stream, cancellable);
    }
}