audrey_sources = [
  'api.vala',
  'application.vala',
  'globalconf.vala',
  'main.vala',
  'mpris.vala',
  'playbin.vala',
  'ui/play_queue.vala',
  'ui/setup.vala',
  'ui/window.vala',
]

audrey_deps = [
  config_dep,
  dependency('gstreamer-1.0', version: '>= 1.24'),
  dependency('gstreamer-audio-1.0', version: '>= 1.24'),
  dependency('gtk4', version: '>= 4.16'),
  dependency('json-glib-1.0', version: '>= 1.10'),
  dependency('libadwaita-1', version: '>= 1.6'),
  dependency('libgcrypt', version: '>= 1.11'),
  dependency('libsecret-1', version: '>= 0.21'),
  dependency('libsoup-3.0', version: '>= 3.6'),
]

blueprints = custom_target(
  'blueprints',
  input: files('ui/play_queue.blp', 'ui/setup.blp', 'ui/window.blp'),
  output: ['play_queue.ui', 'setup.ui', 'window.ui'],
  command: [
    find_program('blueprint-compiler'),
    'batch-compile',
    '@OUTDIR@',
    '@CURRENT_SOURCE_DIR@',
    '@INPUT@',
  ],
)

audrey_sources += gnome.compile_resources(
  'audrey-resources',
  'audrey.gresource.xml',
  c_name: 'audrey',
  dependencies: blueprints,
)

executable(
  'audrey',
  audrey_sources,
  dependencies: audrey_deps,
  include_directories: config_inc,
  install: true,
  vala_args: ['--vapidir', meson.current_source_dir() / 'vapi'],
)