[GtkTemplate (ui = "/eu/callcc/audrey/ui/window.ui")]
class Ui.Window : Adw.ApplicationWindow {
    [GtkChild] private unowned Gtk.ListBox sidebar;
    [GtkChild] private unowned Gtk.ListBoxRow sidebar_play_queue;
    [GtkChild] private unowned Gtk.Stack stack;

    [GtkChild] public unowned Ui.PlayQueue play_queue;
    [GtkChild] public unowned Adw.ButtonRow shuffle_all_tracks;

    private Setup setup;

    private Subsonic.Client api;

    public int volume {
        get { return this.playbin.volume; }
        set { this.playbin.volume = value; }
    }
    public bool mute {
        get { return this.playbin.mute; }
        set { this.playbin.mute = value; }
    }

    public Subsonic.Song? song { get; private set; }

    private Cancellable cancel_loading_art;
    public bool cover_art_loading { get; set; default = false; }
    public Gdk.Paintable playing_cover_art { get; set; }

    public Playbin playbin { get; private set; default = new Playbin (); }
    public ListStore play_queue_store { get; private set; default = new ListStore (typeof (Subsonic.Song)); }

    public Window (Gtk.Application app) {
        Object (application: app);
    }

    construct {
        // TODO: mpris
        // Bus.own_name (
        //     BusType.SESSION,
        //     "org.mpris.MediaPlayer2.audrey",
        //     BusNameOwnerFlags.NONE,
        //     (conn) => {
        //         try {
        //         } catch (IOError e) {
        //             error ("could not register dbus service: %s", e.message);
        //         }
        //     },
        //     () => {},
        //     () => { error ("could not acquire dbus name"); });

        this.playbin.play_queue = this.play_queue_store;

        this.setup = new Setup ();

        this.setup.connected.connect ((api) => {
            this.api = api;
            this.playbin.api = api;

            this.playbin.now_playing.connect ((playbin, now, next) => {
                this.song = now;
                api.scrobble.begin (this.song.id);
                this.play_queue.selection.playbin_select (playbin.play_queue_position);

                if (this.cancel_loading_art != null) {
                    this.cancel_loading_art.cancel ();
                }
                this.cancel_loading_art = new GLib.Cancellable ();

                this.playing_cover_art = Gdk.Paintable.empty (1, 1);
                if (this.song != null) {
                    this.cover_art_loading = true;

                    string song_id = this.song.id;
                    this.api.cover_art.begin (song_id, this.cancel_loading_art, (obj, res) => {
                        try {
                            this.playing_cover_art = Gdk.Texture.for_pixbuf (this.api.cover_art.end (res));
                            this.cover_art_loading = false;
                        } catch (Error e) {
                            if (!(e is IOError.CANCELLED)) {
                                warning ("could not load cover for %s: %s", song_id, e.message);
                                this.cover_art_loading = false;
                            }
                        }
                    });
                }
            });

            this.playbin.stopped.connect (() => {
                this.playing_cover_art = Gdk.Paintable.empty (1, 1);
            });

            this.play_queue.selection.user_selected.connect ((position) => {
                this.playbin.select_track (position);
            });

            this.shuffle_all_tracks.sensitive = true;
            this.shuffle_all_tracks.activated.connect (() => {
                this.shuffle_all_tracks.sensitive = false;
                this.play_queue_store.remove_all ();
                api.get_random_songs.begin (null, (song) => {
                    this.play_queue_store.append (song);
                }, (obj, res) => {
                    try {
                        api.get_random_songs.end (res);
                    } catch (Error e) {
                        error ("could not get random songs: %s", e.message);
                    }
                    this.shuffle_all_tracks.sensitive = true;

                    this.playbin.select_track (0);
                });
            });
        });
        this.setup.load ();

        this.sidebar.select_row (this.sidebar.get_row_at_index (0));
    }

    [GtkCallback] private void on_sidebar_row_activated (Gtk.ListBoxRow row) {
        if (row == this.sidebar_play_queue) {
            this.stack.set_visible_child_name("play_queue");
        }
    }

    [GtkCallback] private string format_timestamp (double s) {
        return "%02d:%02d".printf (((int) s)/60, ((int) s)%60);
    }

    [GtkCallback] private bool on_play_position_seek (Gtk.Range range, Gtk.ScrollType scroll_type, double value) {
        this.playbin.seek ((int64) value);
        return false;
    }

    [GtkCallback] private void on_play_pause_clicked () {
        if (this.playbin.state == PlaybinState.PLAYING) {
            this.playbin.pause();
        } else {
            this.playbin.play();
        }
    }

    [GtkCallback] private string play_pause_icon_name (PlaybinState state) {
        if (state == PlaybinState.PLAYING) {
            return "media-playback-pause";
        } else {
            return "media-playback-start";
        }
    }

    [GtkCallback] private bool playbin_active (PlaybinState state) {
        return state != PlaybinState.STOPPED;
    }

    [GtkCallback] private string mute_button_icon_name (bool mute) {
        return mute ? "audio-volume-muted" : "audio-volume-high";
    }

    [GtkCallback] private void on_mute_toggle () {
        this.mute = !this.mute;
    }

    [GtkCallback] private void on_skip_forward_clicked () {
        this.playbin.next_track ();
    }

    [GtkCallback] private void on_skip_backward_clicked () {
        this.playbin.prev_track ();
    }

    [GtkCallback] private void show_setup_dialog () {
        this.setup.present (this);
    }

    [GtkCallback] private void seek_backward () {
        // 10 seconds
        double new_position = playbin.position - 10.0;
        if (new_position < 0.0) new_position = 0.0;
        this.playbin.seek (new_position);
    }

    [GtkCallback] private void seek_forward () {
        // 10 seconds
        double new_position = playbin.position + 10.0;
        if (new_position > this.playbin.duration) new_position = this.playbin.duration;
        this.playbin.seek (new_position);
    }

    [GtkCallback] private string song_title (Subsonic.Song? song) {
        return song == null ? "" : song.title;
    }

    [GtkCallback] private string song_artist (Subsonic.Song? song) {
        return song == null ? "" : song.artist;
    }

    [GtkCallback] private string song_album (Subsonic.Song? song) {
        return song == null ? "" : song.album;
    }
}