wavelet_sources = [
  'api.vala',
  'application.vala',
  'artist_list.vala',
  'main.vala',
  'play_queue.vala',
  'setup.vala',
  'song_list.vala',
  'window.vala',
]

wavelet_deps = [
  config_dep,
  dependency('gtk4'),
  dependency('json-glib-1.0'),
  dependency('libadwaita-1', version: '>= 1.4'),
  dependency('libsoup-3.0'),
  dependency('sqlite3'),
]

blueprints = custom_target('blueprints',
  input: files(
    'artist_list.blp',
    'play_queue.blp',
    'setup.blp',
    'song_list.blp',
    'window.blp',
  ),
  output: [
    'artist_list.ui',
    'play_queue.ui',
    'setup.ui',
    'song_list.ui',
    'window.ui',
  ],
  command: [
    find_program('blueprint-compiler'),
    'batch-compile',
    '@OUTDIR@',
    '@CURRENT_SOURCE_DIR@',
    '@INPUT@',
  ],
)

wavelet_sources += gnome.compile_resources('wavelet-resources',
  'wavelet.gresource.xml',
  c_name: 'wavelet',
  dependencies: blueprints,
)

executable('wavelet', wavelet_sources,
  dependencies: wavelet_deps,
  include_directories: config_inc,
       install: true,
)