[GtkTemplate (ui = "/eu/callcc/Wavelet/window.ui")]
class Wavelet.Window : Adw.ApplicationWindow {
    [GtkChild] private unowned Gtk.ListBox sidebar;
    [GtkChild] private unowned Gtk.ListBoxRow sidebar_play_queue;
    [GtkChild] private unowned Gtk.Stack stack;

    [GtkChild] public unowned Wavelet.PlayQueue play_queue;
    [GtkChild] public unowned Adw.ButtonRow shuffle_all_tracks;

    private Wavelet.Setup setup;

    public bool playing { get; private set; default = false; }
    
    [GtkChild] private unowned Gtk.Scale play_position;
    public int64 position { get; private set; }

    public double volume {
        get { return this.playbin.volume; }
        set { this.playbin.volume = value; }
    }
    public bool mute {
        get { return this.playbin.mute; }
        set { this.playbin.mute = value; }
    }

    public Song? song { get; set; default = null; }

    private Cancellable cancel_loading_art;
    public bool cover_art_loading { get; set; default = false; }
    public Gdk.Paintable playing_cover_art { get; set; }
    private Gdk.Paintable next_cover_art;

    internal Playbin playbin { get; default = new Playbin (); }

    public Window (Gtk.Application app) {
        Object (application: app);

        var provider = new Gtk.CssProvider ();
        provider.load_from_resource("/eu/callcc/Wavelet/wavelet.css");

        Gtk.StyleContext.add_provider_for_display (Gdk.Display.get_default (), provider, Gtk.STYLE_PROVIDER_PRIORITY_APPLICATION);

        this.close_request.connect (() => {
            app.quit ();
            return false;
        });
    }

    construct {
        Bus.own_name (
            BusType.SESSION,
            "org.mpris.MediaPlayer2.wavelet",
            BusNameOwnerFlags.NONE,
            (conn) => {
                try {
                    // TODO: mpris
                } catch (IOError e) {
                    error ("could not register dbus service: %s", e.message);
                }
            },
            () => {},
            () => { error ("could not acquire dbus name"); });

        this.setup = new Wavelet.Setup ();

        this.setup.connected.connect ((api) => {
            public_api = api;

            this.shuffle_all_tracks.sensitive = true;
            this.shuffle_all_tracks.activated.connect (() => {
                this.shuffle_all_tracks.sensitive = false;
                this.play_queue.clear ();
                api.get_random_songs.begin (null, (song) => {
                    this.play_queue.queue (song);
                }, (obj, res) => {
                    try {
                        api.get_random_songs.end (res);
                    } catch (Error e) {
                        error ("could not get random songs: %s", e.message);
                    }
                    this.shuffle_all_tracks.sensitive = true;

                    this.play_queue.restart ();
                });
            });

            playbin.stream_started.connect (this.play_queue.on_stream_start);

            this.play_queue.now_playing.connect ((song) => {
                this.playing = true;
                this.song = song;
                api.scrobble.begin (song.id);
            });

            this.play_queue.play_now.connect ((song) => {
                playbin.play_now.begin (api.stream_uri (song.id));
            });
            this.play_queue.play_next.connect ((song) => {
                if (song == null) {
                    playbin.set_next_uri (null);
                } else {
                    playbin.set_next_uri (api.stream_uri (song.id));
                }
            });
        });
        this.setup.load ();

        this.sidebar.select_row (this.sidebar.get_row_at_index (0));

        this.notify["song"].connect (() => {
            if (this.cancel_loading_art != null) {
                this.cancel_loading_art.cancel ();
            }
            this.cancel_loading_art = new Cancellable ();

            this.playing_cover_art = Gdk.Paintable.empty (100, 100);
            if (this.song != null) {
                this.cover_art_loading = true;

                string song_id = this.song.id;
                public_api.cover_art.begin (song_id, 100, this.cancel_loading_art, (obj, res) => {
                    try {
                        this.playing_cover_art = Gdk.Texture.for_pixbuf (public_api.cover_art.end (res));
                        this.cover_art_loading = false;
                    } catch (Error e) {
                        if (!(e is IOError.CANCELLED)) {
                            warning ("could not load cover for %s: %s", song_id, e.message);
                            this.cover_art_loading = false;
                        }
                    }
                });
            }
        });
        this.song = null;

        this.playbin.set_position.connect ((sender, new_position) => {
            // only set if we aren't seeking
            if (this.seek_timeout_id == 0) {
                this.position = new_position;
            }
        });
    }

    [GtkCallback] private void on_sidebar_row_activated (Gtk.ListBoxRow row) {
        if (row == this.sidebar_play_queue) {
            this.stack.set_visible_child_name("play_queue");
        }
    }

    [GtkCallback] private string format_timestamp (int64 ns) {
        int64 ms = ns / 1000000;
        int s = (int) (ms / 1000);
        return "%02d:%02d".printf (s/60, s%60);
    }

    // same timeout logic as https://code.videolan.org/videolan/npapi-vlc/blob/6eae0ffb9cbaf8f6e04423de2ff38daabdf7cae3/npapi/vlcplugin_gtk.cpp#L312
    private uint seek_timeout_id = 0;
    [GtkCallback] private bool on_play_position_seek (Gtk.Range range, Gtk.ScrollType scroll_type, double value) {
        if (this.seek_timeout_id == 0) {
            this.seek_timeout_id = Timeout.add (500, () => {
                playbin.seek.begin ((int64) range.adjustment.value, (obj, res) => {
                    this.seek_timeout_id = 0;
                });
                return false;
            });
        }
        return false;
    }

    [GtkCallback] private void on_play_pause_clicked () {
        if (this.playing) {
            this.playbin.pause();
            this.playing = false;
        } else {
            this.playbin.play();
            this.playing = true;
        }
    }

    [GtkCallback] private string play_button_icon_name (bool playing) {
        return playing ? "media-playback-pause" : "media-playback-start";
    }

    [GtkCallback] private string mute_button_icon_name (bool mute) {
        return mute ? "audio-volume-muted" : "audio-volume-high";
    }

    [GtkCallback] private void on_mute_toggle () {
        this.mute = !this.mute;
    }

    [GtkCallback] private void on_skip_forward_clicked () {
        this.play_queue.skip_forward ();
    }

    [GtkCallback] private void on_skip_backward_clicked () {
        this.play_queue.skip_backward ();
    }

    [GtkCallback] private void show_setup_dialog () {
        this.setup.present (this);
    }
}