wavelet_sources = [
  'api.vala',
  'application.vala',
  'main.vala',
  'mpris.vala',
  'play_queue.vala',
  'playbin.vala',
  'setup.vala',
  'window.vala',
]

wavelet_deps = [
  config_dep,
  dependency('gstreamer-1.0'),
  dependency('gstreamer-audio-1.0'),
  dependency('gtk4'),
  dependency('json-glib-1.0'),
  dependency('libadwaita-1', version: '>= 1.4'),
  dependency('libsoup-3.0'),
  dependency('sqlite3'),
]

blueprints = custom_target('blueprints',
  input: files(
    'play_queue.blp',
    'setup.blp',
    'window.blp',
  ),
  output: [
    'play_queue.ui',
    'setup.ui',
    'window.ui',
  ],
  command: [
    find_program('blueprint-compiler'),
    'batch-compile',
    '@OUTDIR@',
    '@CURRENT_SOURCE_DIR@',
    '@INPUT@',
  ],
)

wavelet_sources += gnome.compile_resources('wavelet-resources',
  'wavelet.gresource.xml',
  c_name: 'wavelet',
  dependencies: blueprints,
)

executable('wavelet', wavelet_sources,
  dependencies: wavelet_deps,
  include_directories: config_inc,
       install: true,
)