audrey/src/meson.build

audrey_sources = [
  'api.vala',
  'application.vala',
  'main.vala',
  'mpris.vala',
  'playbin.vala',
  'ui/play_queue.vala',
  'ui/setup.vala',
  'ui/window.vala',
]

audrey_deps = [
  config_dep,
  dependency('gstreamer-1.0'),
  dependency('gstreamer-audio-1.0'),
  dependency('gtk4'),
  dependency('json-glib-1.0'),
  dependency('libadwaita-1', version: '>= 1.4'),
  dependency('libsoup-3.0'),
  dependency('sqlite3'),
]

blueprints = custom_target('blueprints',
  input: files(
    'ui/play_queue.blp',
    'ui/setup.blp',
    'ui/window.blp',
  ),
  output: [
    'play_queue.ui',
    'setup.ui',
    'window.ui',
  ],
  command: [
    find_program('blueprint-compiler'),
    'batch-compile',
    '@OUTDIR@',
    '@CURRENT_SOURCE_DIR@',
    '@INPUT@',
  ],
)

audrey_sources += gnome.compile_resources('audrey-resources',
  'audrey.gresource.xml',
  c_name: 'audrey',
  dependencies: blueprints,
)

executable('audrey', audrey_sources,
  dependencies: audrey_deps,
  include_directories: config_inc,
       install: true,
)