audrey/src/play_queue.vala

/* play_queue.vala
 *
 * Copyright 2024 Erica Z
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU Affero General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU Affero General Public License for more details.
 *
 * You should have received a copy of the GNU Affero General Public License
 * along with this program.  If not, see <https://www.gnu.org/licenses/>.
 *
 * SPDX-License-Identifier: AGPL-3.0-or-later
 */

[GtkTemplate (ui = "/eu/callcc/Wavelet/play_queue.ui")]
public class Wavelet.PlayQueue : Adw.NavigationPage {
    [GtkChild] private unowned Gtk.ListView list_view;

    private ListStore songs;

    // this is the index of the song that will play on next on_stream_start
    private uint next_stream_index;

    public signal void play_now (Song song);
    public signal void now_playing (Song song);
    public signal void play_next (Song? song);

    construct {
        this.songs = new ListStore (typeof (Song));
        this.next_stream_index = 0;

        this.list_view.model = new Gtk.NoSelection (this.songs);
    }

    public void clear () {
        this.songs.remove_all ();
    }

    public void queue (Song song) {
        uint new_index = this.songs.get_n_items ();
        this.songs.append (song);
        if (new_index == next_stream_index) {
            this.play_next (song);
        }
    }

    [GtkCallback] private void on_song_activate (uint position) {
        this.next_stream_index = position;
        Song song = (Song) this.songs.get_item (position);
        this.play_next (song);
        this.play_now (song);
    }

    internal void on_stream_start (Playbin playbin) {
        Song song = (Song) this.songs.get_item (this.next_stream_index);
        this.now_playing (song);

        // prepare for next song ahead of time (gapless)
        this.next_stream_index += 1;
        Song? next_song = (Song?) this.songs.get_item (this.next_stream_index);
        this.play_next (next_song);
    }

    internal void restart () {
        this.next_stream_index = 0;
        Song song = (Song) this.songs.get_item (0);
        this.play_next (song);
        this.play_now (song);
    }
}